Baseline: omarchy.indicators as shipped

Indicators.qml and the six indicator files exactly as they ship in
omarchy-dev 4.0.0.r1744.gf002044, alongside the manifest `omarchy plugin
clone` generates.

Kept on its own branch so `git diff stock..master` shows precisely what
this fork changes.

indicators/Dictation.qml

@@ -0,0 +1,38 @@
+import QtQuick
+import Quickshell.Io
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  property string state: "idle"
+  property string icon: ""
+
+  active: state === "recording"
+  activeText: icon
+  inactiveText: "󰍬"
+  activeTooltipText: state
+  inactiveTooltipText: "Dictate"
+
+  function update(raw) {
+    var data = extractData(raw)
+
+    state = String(data.alt || data.class || "idle")
+    if (state === "recording") icon = "󰍬"
+    else if (state === "transcribing") icon = "󰔟"
+    else icon = ""
+  }
+
+  Process {
+    command: ["bash", "-c", "omarchy-voxtype-status"]
+    running: true
+    stdout: SplitParser {
+      onRead: function(data) { root.update(data) }
+    }
+  }
+
+  onPressed: function() {
+    if (!root.bar) return
+    root.bar.run("omarchy-voxtype-config")
+  }
+}

indicators/Dnd.qml

@@ -0,0 +1,22 @@
+import QtQuick
+import qs.Commons
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  readonly property var notificationService: bar?.shell?.firstPartyServiceFor("omarchy.notifications")
+  readonly property bool dnd: notificationService ? notificationService.doNotDisturb : false
+
+  active: dnd
+  activeText: "󰂛"
+  inactiveText: "󰂛"
+  activeTooltipText: "Allow Notifications"
+  inactiveTooltipText: "Silence Notifications"
+
+  onPressed: function() {
+    if (root.notificationService) {
+      root.notificationService.setDoNotDisturb(!root.notificationService.doNotDisturb)
+    }
+  }
+}

indicators/NightLight.qml

@@ -0,0 +1,20 @@
+import QtQuick
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  readonly property var nightlightService: bar?.shell?.firstPartyServiceFor("omarchy.nightlight")
+
+  active: nightlightService ? nightlightService.enabled : false
+  activeText: "󰔎"
+  inactiveText: "󰔎"
+  activeTooltipText: "Day Light"
+  inactiveTooltipText: "Night Light"
+
+  function toggle() {
+    if (root.nightlightService) root.nightlightService.setNightlight(!root.active)
+  }
+
+  onPressed: function() { root.toggle() }
+}

indicators/Reminder.qml

@@ -0,0 +1,59 @@
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  property int reminderCount: 0
+  property string tooltip: ""
+
+  active: reminderCount > 0
+  activeText: "󰢌"
+  inactiveText: "󰢌"
+  activeTooltipText: tooltip
+  inactiveTooltipText: tooltip
+
+  function refresh() {
+    if (!jsonProc.running) jsonProc.running = true
+  }
+
+  function openReminderFlow() {
+    Quickshell.execDetached(["omarchy-reminder", "-i"])
+  }
+
+  function update(raw) {
+    var data = extractData(raw)
+    reminderCount = Number(data.count || 0)
+    tooltip = String(data.tooltip || "")
+  }
+
+  Component.onCompleted: refresh()
+
+  Connections {
+    target: root.indicatorHost
+    ignoreUnknownSignals: true
+    function onRefreshRequested() { root.refresh() }
+  }
+
+  Process {
+    id: jsonProc
+    command: ["omarchy-reminder", "show", "--json"]
+    stdout: StdioCollector {
+      waitForEnd: true
+      onStreamFinished: root.update(text)
+    }
+    onExited: function(exitCode) {
+      if (exitCode !== 0) {
+        root.reminderCount = 0
+        root.tooltip = ""
+      }
+    }
+  }
+
+  onPressed: function() {
+    if (root.reminderCount > 0) Quickshell.execDetached(["omarchy-reminder", "show"])
+    else root.openReminderFlow()
+  }
+}

indicators/ScreenRecording.qml

@@ -0,0 +1,43 @@
+import QtQuick
+import Quickshell.Io
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  property bool recording: false
+
+  active: recording
+  activeText: "󰻂"
+  inactiveText: "󰻂"
+  activeTooltipText: "Stop recording"
+  inactiveTooltipText: "Screen Recording"
+
+  function refresh() {
+    if (!root.bar || statusProc.running) return
+    statusProc.command = ["pgrep", "--quiet", "-f", "^gpu-screen-recorder"]
+    statusProc.running = true
+  }
+
+  onBarChanged: refresh()
+  Component.onCompleted: refresh()
+
+  Connections {
+    target: root.indicatorHost
+    ignoreUnknownSignals: true
+    function onRefreshRequested() { root.refresh() }
+  }
+
+  Process {
+    id: statusProc
+    onExited: function(exitCode) {
+      root.recording = exitCode === 0
+    }
+  }
+
+  onPressed: function() {
+    if (root.bar) {
+      root.bar.run(root.recording ? "omarchy-capture-screenrecording --stop-recording" : "omarchy-menu toggle trigger.capture.screenrecord")
+    }
+  }
+}

indicators/StayAwake.qml

@@ -0,0 +1,20 @@
+import QtQuick
+import qs.Ui
+
+BarIndicator {
+  id: root
+
+  readonly property var idleService: bar?.shell?.firstPartyServiceFor("omarchy.idle")
+
+  active: idleService ? idleService.stayAwake : false
+  activeText: "󰅶"
+  inactiveText: "󰅶"
+  activeTooltipText: "Allow Idle Lock & Screensaver"
+  inactiveTooltipText: "Stay Awake"
+
+  function toggle() {
+    if (root.idleService) root.idleService.setIdleEnabled(root.active)
+  }
+
+  onPressed: function() { root.toggle() }
+}